VbScript-Accessing the value of a property from results filtered by a certain condition

Question

Hello, 
 I am developing a code that will run in mfiles with Vbscript. What I want to do here is to access the value of a feature in the result value returned to me as a result of the search conditions I sent. I wonder how can I do this? I would be very happy if anyone with knowledge on the subject could help. 
 Thans for your help.

Ne0Tr0n · Answer

HI, 
 As Karl said it depends on the goal how you approach it. 
 It would have been nice if you had posted the code or at least the fragment where you are having difficulty. 
 Anyway here is some sample code how you can access the properties of a found object using item 
 ' Create search Condisions
Set oSCs = CreateObject("MFilesAPI.SearchConditions")

'Add Search Condition for filtering Class by ClassID
Set oSCClass = CreateObject("MFilesAPI.SearchCondition") 
oSCClass.ConditionType = MFConditionTypeEqual
oSCClass.Expression.DataPropertyValuePropertyDef = 100 
oSCClass.TypedValue.SetValue MFDatatypeLookup, iCLSalesDocument
oSCs.Add -1, oSCClass

'Add Search Condition for filtering Obejects(Documents) from Class SalesDocument by BuildIn property Name or Title 
Set oSearchCondition = CreateObject("MFilesAPI.SearchCondition")
oSearchCondition.ConditionType = MFConditionTypeEqual
oSearchCondition.Expression.DataPropertyValuePropertyDef = 0
oSearchCondition.TypedValue.SetValue MFDatatypeText, szPDInvoiceNumber
oSCs.Add -1, oSearchCondition

'Add Search Condition for exclude deleted objects
Set oSearchNonDeleted = CreateObject("MFilesAPI.SearchCondition") 
oSearchNonDeleted.ConditionType = MFConditionTypeEqual
oSearchNonDeleted.Expression.DataStatusValueType = MFStatusTypeDeleted
oSearchNonDeleted.TypedValue.SetValue MFDatatypeBoolean, False
oSCs.Add -1, oSearchNonDeleted

'Execute Search
Set oSearchResults = Vault.ObjectSearchOperations.SearchForObjectsByConditionsEx(oSCs,MFSearchFlagNone, False)

If oSearchResults.Count = 1 Then
	Set oBindProperties = Vault.ObjectPropertyOperations.GetProperties(oSearchResults.Item(1).ObjVer, True)
Else
	'Something went wrong code
End If

VbScript-Accessing the value of a property from results filtered by a certain condition

Top Replies